AWK(1) | General Commands Manual | AWK(1)

# NAME

`awk` — pattern-directed scanning and processing language

# SYNOPSIS

`awk` | [`-F` fs] [`-v` var`=`value] [`-safe`] [`-d`[N]] [prog | `-f` progfile] file ...

`awk` | `-version`

# DESCRIPTION

`awk` is the Bell Labs' implementation of the AWK programming language as described in the The AWK Programming Language by A.V. Aho, B.W. Kernighan, P.J. Weinberger.

`awk` scans each input file for lines that match any of a set of patterns specified literally in prog or in one or more files specified as `-f` progfile. With each pattern there can be an associated action that will be performed when a line of a file matches the pattern. Each line is matched against the pattern portion of every pattern-action statement; the associated action is performed for each matched pattern. The file name - means the standard input. Any file of the form var`=`value is treated as an assignment, not a filename, and is executed at the time it would have been opened if it were a filename. The option `-v` followed by var`=`value is an assignment to be done before prog is executed; any number of `-v` options may be present. The `-F` fs option defines the input field separator to be the regular expression fs.

The options are as follows:

`-d`[N]
  Set debug level to specified number N. If the number is omitted, debug level is set to 1.
`-f` filename
  Read the AWK program source from specified file filename, instead of the first command line argument. Multiple `-f` options may be specified.
`-F` fs
  Set the input field separator FS to the regular expression fs.
`-mr` NNN, `-mf` NNN
  Obsolete, no longer needed options. Set limit on maximum record or fields number.
`-safe`
  Potentially unsafe functions such as `system`() make the program abort (with a warning message).
`-v` var`=`value
  Assign the value value to the variable var before prog is executed. Any number of `-v` options may be present.
`-version`
  Print `awk` version on standard output and exit.

An input line is normally made up of fields separated by white space, or by the regular expression the built-in variable FS is set to. If FS is null, the input line is split into one field per character. The fields are denoted `$`1, `$`2, ..., while `$`0 refers to the entire line. Setting any other field causes the re-evaluation of `$`0 Assigning to `$`0 resets the values of all other fields and the NF built-in variable.

A pattern-action statement has the form

pattern `{` action `}`

A missing `{` action `}` means print the line; a missing pattern always matches. Pattern-action statements are separated by newlines or semicolons.

An action is a sequence of statements. Statements are terminated by semicolons, newlines or right braces. An empty expression-list stands for `$`0. String constants are quoted `""`, with the usual C escapes recognized within. Expressions take on string or numeric values as appropriate, and are built using the Operators (see next subsection). Variables may be scalars, array elements (denoted x[i]) or fields. Variables are initialized to the null string. Array subscripts may be any string, not necessarily numeric; this allows for a form of associative memory. Multiple subscripts such as [i`,`j`,`k] are permitted; the constituents are concatenated, separated by the value of SUBSEP.

## Operators

`awk` operators, in order of decreasing precedence, are:

`(`...`)`
  Grouping
`$`
  Field reference
`++ --`
  Increment and decrement, can be used either as postfix or prefix.
`^`
  Exponentiation (the `**` form is also supported, and `**=` for the assignment operator).
+ - !
  Unary plus, unary minus and logical negation.
* / %
  Multiplication, division and modulus.
+ -
  Addition and subtraction.
space
  String concatenation.
`< >`
`<= >=`
`!= ==`
  Regular relational operators
`~ !~`
  Regular expression match and not match
`in`
  Array membership
`&&`
  Logical AND
`||`
  Logical OR
`?:`
  C conditional expression. This is used as expr1 `?` expr2 `:` expr3. If expr1 is true, the result value is expr2, otherwise it is expr3. Only one of expr2 and expr3 is evaluated.
`= += -=`
`*= /= %= ^=`
  Assignment and Operator-Assignment

## Control Statements

The control statements are as follows:

`if (`expression`)` statement [`else` statement]
`while (`expression`)` statement
`for (`expression`;` expression`;` expression`)` statement
`for (`var `in` array`)` statement
`do` statement `while (`expression`)`
`break`
`continue`
`{` [statement ...] `}`
expression
  Commonly var `=` expression
`return` [expression]
`next`
  Skip remaining patterns on this input line
`nextfile`
  Skip rest of this file, open next, start at top
`delete` array`[`expression`]`
  Delete an array element
`delete` array
  Delete all elements of an array
`exit` [expression]
  Exit immediately; status is expression

## I/O Statements

The input/output statements are as follows:

`close`(expr)
  Closes the file or pipe expr. Returns zero on success; otherwise nonzero.
`fflush`(expr)
  Flushes any buffered output for the file or pipe expr. Returns zero on success; otherwise nonzero.
`getline` [var]
  Set var (or `$`0 if var is not specified) to the next input record from the current input file. `getline` returns 1 for a successful input, 0 for end of file, and -1 for an error.
`getline` [var] `<` file
  Set var (or `$`0 if var is not specified) to the next input record from the specified file file.
expr `| getline`
  Pipes the output of expr into `getline`; each call of `getline` returns the next line of output from expr.
`print` [expr-list] [redirection]
  Print arguments separated by the current output field separator OFS, and terminated by the output record separator ORS.
`printf` format[`,` expr-list] [redirection]
  Format and print its expression list according to format. See printf(3) for list of supported formats and their meaning.

Both `print` and `printf` statements write to standard output by default. The output is written to the file or pipe specified by redirection if one is supplied, as follows: `>` file, `>>` file, or `|` expr. Both file and expr may be literal names or parenthesized expressions; identical string values in different statements denote the same open file. For that purpose the file names /dev/stdin, /dev/stdout, and /dev/stderr refer to the program's stdin, stdout, and stderr respectively (and are unrelated to the fd(4) devices of the same names).

## Mathematical and Numeric Functions

AWK has the following mathematical and numerical functions built-in:

`atan2`(x, y)
  Returns the arctangent of x`/`y in radians. See also atan2(3).
`cos`(expr)
  Computes the cosine of expr, measured in radians. See also cos(3).
`exp`(expr)
  Computes the exponential value of the given argument expr. See also exp(3).
`int`(expr)
  Truncates expr to integer.
`log`(expr)
  Computes the value of the natural logarithm of argument expr. See also log(3).
`rand`()
  Returns random number between 0 and 1.
`sin`(expr)
  Computes the sine of expr, measured in radians. See also sin(3).
`sqrt`(expr)
  Computes the non-negative square root of expr. See also sqrt(3).
`srand`([expr])
  Sets seed for random number generator (`rand`()) and returns the previous seed.

## String Functions

AWK has the following string functions built-in:

`gensub`(r, s, h [t]);
  Search the target string t for matches of the regular expression r. If h is a string beginning with ‘`g`’ or ‘`G`’, then replace all matches of r with s. Otherwise, h is a number indicating which match of r to replace. If no t is supplied, `$`0 is used instead. Unlike `sub`() and `gsub`(), the modified string is returned as the result of the function, and the original target is not changed. Note that the ‘`\`n’ sequences (backreferences) within replacement string s supported by GNU `awk` are not supported at this moment.
`gsub`(r, s [t]);
  Same as `sub`() except that all occurrences of the regular expression are replaced; `sub`() and `gsub`() return the number of replacements.
`index`(s, t)
  The position in s where the string t occurs, or 0 if it does not.
`length`[([string])]
  The length of its argument taken as a string, or of `$`0 if no argument.
`match`(s, r)
  The position in s where the regular expression r occurs, or 0 if it does not. The variables RSTART and RLENGTH are set to the position and length of the matched string.
`split`(s, a [fs]);
  Splits the string s into array elements a`[1]`, a`[2]`, ..., a`[`n`]`, and returns n. The separation is done with the regular expression fs or with the field separator FS if fs is not given. An empty string as field separator splits the string into one array element per character.
`sprintf`(fmt, expr, ...)
  Returns the string resulting from formatting expr according to the printf(3) format fmt.
`sub`(r, s [t]);
  Substitutes s for the first occurrence of the regular expression r in the target string t. If t is not given, `$`0 is used.
`substr`(s, m [n]);
  Returns the at most n-character substring of s starting at position m, counted from 1. If n is omitted, the rest of s is returned.
`tolower`(str)
  Returns a copy of str with all upper-case characters translated to their corresponding lower-case equivalents.
`toupper`(str)
  Returns a copy of str with all lower-case characters translated to their corresponding upper-case equivalents.

## Time Functions

This `awk` provides the following two functions for obtaining time stamps and formatting them:

`systime`()
  Returns the value of time in seconds since the start of Unix Epoch (midnight, January 1, 1970, Coordinated Universal Time). See also time(3).
`strftime`([format [timestamp]]);
  Formats the time timestamp according to the string format. timestamp should be in same form as value returned by `systime`(). If timestamp is missing, current time is used. If format is missing, a default format equivalent to the output of date(1) would be used. See the specification of ANSI C strftime(3) for the format conversions which are supported.

## Other built-in functions

`system`(cmd)
  Executes cmd and returns its exit status.

## Patterns

Patterns are arbitrary Boolean combinations (with `! || &&`) of regular expressions and relational expressions. Regular expressions are as in egrep(1). Isolated regular expressions in a pattern apply to the entire line. Regular expressions may also occur in relational expressions, using the operators `~` and `!~`. `/`re`/` is a constant regular expression; any string (constant or variable) may be used as a regular expression, except in the position of an isolated regular expression in a pattern.

A pattern may consist of two patterns separated by a comma; in this case, the action is performed for all lines from an occurrence of the first pattern though an occurrence of the second.

A relational expression is one of the following:

expression matchop regular-expression
expression relop expression
expression `in` array-name
`(`expr`,` expr`,` ... `) in` array-name

where a relop is any of the six relational operators in C, and a matchop is either `~` (matches) or `!~` (does not match). A conditional is an arithmetic expression, a relational expression, or a Boolean combination of these.

The special patterns `BEGIN` and `END` may be used to capture control before the first input line is read and after the last. `BEGIN` and `END` do not combine with other patterns.

If an awk program consists of only actions with the pattern `BEGIN`, and the `BEGIN` action contains no `getline` statement, awk exits without reading its input when the last statement in the last `BEGIN` action is executed. If an awk program consists of only actions with the pattern `END` or only actions with the patterns `BEGIN` and `END`, the input is read before the statements in the `END` actions are executed.

## Built-in Variables

Variable names with special meanings:

ARGC
  argument count, assignable
ARGV
  argument array, assignable; non-null members are taken as filenames
CONVFMT
  conversion format used when converting numbers (default `"%.6g"`)
ENVIRON
  array of environment variables; subscripts are names.
FILENAME
  the name of the current input file
FNR
  ordinal number of the current record in the current file
FS
  regular expression used to separate fields; also settable by option `-F` fs.
NF
  number of fields in the current record
NR
  ordinal number of the current record
OFMT
  output format for numbers (default `"%.6g"`)
OFS
  output field separator (default blank)
ORS
  output record separator (default newline)
RS
  input record separator (default newline)
RSTART
  position of the first character matched by `match`(); 0 if no match.
RLENGTH
  length of the string matched by `match`(); -1 if no match.
SUBSEP
  separates multiple subscripts (default `034`)

## Functions

Functions may be defined (at the position of a pattern-action statement) thus:

    function foo(a, b, c) { ...; return x }

Parameters are passed by value if scalar and by reference if array name; functions may be called recursively. Parameters are local to the function; all other variables are global. Thus local variables may be created by providing excess parameters in the function definition.

# EXAMPLES

Print lines longer than 72 characters. `length`() defaults to `$`0 and the empty parens can also be omitted in this case:

`length > 72`

Print first two fields in opposite order:

`{ print $2, $1 }`

Same, with input fields separated by comma and/or blanks and tabs:

    BEGIN { FS = ",[ \t]*|[ \t]+" }
          { print $2, $1 }

Add up first column, print sum and average:

    { s += $1 }
    END { print "sum is", s, "average is", s/NR }

Print all lines between start/stop pairs:

`/start/, /stop/`

Simulate echo(1):

    BEGIN  {
            for (i = 1; i < ARGC; ++i)
            printf("%s%s", ARGV[i], i==ARGC-1?"\n":" ")
    }

Another way to do the same that demonstrates field assignment and `$`0 re-evaluation:

`BEGIN { for (i = 1; i < ARGC; ++i) $i = ARGV[i]; print }`

Print an error message to standard error:

    { print "error!" > "/dev/stderr" }

# SEE ALSO

egrep(1), lex(1), sed(1), atan2(3), cos(3), exp(3), log(3), sin(3), sqrt(3), strftime(3), time(3)

A.V. Aho, B.W. Kernighan, P.J. Weinberger, The AWK Programming Language, Addison-Wesley, 1988. ISBN 0-201-07981-X

AWK Language Programming, Edition 1.0, published by the Free Software Foundation, 1995

# HISTORY

`nawk` has been the default system `awk` since NetBSD 2.0, replacing the previously used GNU `awk`.

# BUGS

There are no explicit conversions between numbers and strings. To force an expression to be treated as a number add 0 to it; to force it to be treated as a string concatenate "" to it.

The scope rules for variables in functions are a botch; the syntax is worse.

Only eight-bit characters sets are handled correctly.

July 5, 2022 | NetBSD 11.99